Delphi在另一个图像上绘制png文件的一部分

html5 • • 问答

我正在使用此函数在特定位置的 TImage 上绘制 png：

procedure TForm1.PlacePNG(nam: string; px, py: Integer);
var
  vPic: TPicture;
  vSrc: TGraphic;
begin
  vPic := TPicture.Create;
  try
    vPic.LoadFromFile(Nam);
    vSrc := vPic.Graphic;
    Image1.Canvas.Draw(px, py, vSrc);
  finally
    vPic.Free;
  end;
end;

我的问题：在不失去透明度的情况下，对 png 文件的一部分执行此操作的最佳方法是什么？

回答

这是个有趣的问题！

当然，绘制整个PNG 是微不足道的：

procedure TForm1.FormCreate(Sender: TObject);
var
  bg, fg: TPngImage;
begin

  bg := TPngImage.Create;
  try
    bg.LoadFromFile('K:bg.png');
    fg := TPngImage.Create;
    try
      fg.LoadFromFile('K:fg.png');
      Image1.Picture.Graphic := bg;
      Image2.Picture.Graphic := fg;
      fg.Draw(bg.Canvas, Rect(0, 0, fg.Width, fg.Height));
      Image3.Picture.Graphic := bg;
    finally
      fg.Free;
    end;
  finally
    bg.Free;
  end;

end;

要仅绘制一部分，一种可能的解决方案是获取 32-bpp RGBA 位图形式的图像，然后使用 Windows API，具体而言，该AlphaBlend函数：

procedure TForm1.FormCreate(Sender: TObject);
var
  bg, fg: TPngImage;
  bgbm, fgbm: TBitmap;
  BlendFunction: TBlendFunction;
begin

  // Load background PNG
  bg := TPngImage.Create;
  try

    bg.LoadFromFile('K:bg.png');

    // Load foreground PNG
    fg := TPngImage.Create;
    try

      fg.LoadFromFile('K:fg.png');

      // Preview background and foreground
      Image1.Picture.Graphic := bg;
      Image2.Picture.Graphic := fg;

      // Create background BMP
      bgbm := TBitmap.Create;
      try

        bgbm.Assign(bg);

        // Create foreground BMP
        fgbm := TBitmap.Create;
        try

          fgbm.Assign(fg);

          // Blend PART OF foreground BMP onto background BMP
          BlendFunction.BlendOp := AC_SRC_OVER;
          BlendFunction.BlendFlags := 0;
          BlendFunction.SourceConstantAlpha := 255;
          BlendFunction.AlphaFormat := AC_SRC_ALPHA;
          if not Winapi.Windows.AlphaBlend(
            bgbm.Canvas.Handle,
            100,
            100,
            200,
            200,
            fgbm.Canvas.Handle,
            200,
            200,
            200,
            200,
            BlendFunction
          ) then
            RaiseLastOSError;

          // Preview result
          Image3.Picture.Graphic := bgbm;

        finally
          fgbm.Free;
        end;

      finally
        bgbm.Free;
      end;

    finally
      fg.Free;
    end;

  finally
    bg.Free;
  end;

end;

以上是Delphi在另一个图像上绘制png文件的一部分的全部内容。
THE END
分享
二维码
< <上一篇
下一篇>>