当多部电影在DBpedia中具有相同的名称时，无法获取给定电影名称的演员姓名

html5 • • 问答

我试图通过我的 sparql 查询获取给定电影片名的演员姓名（我也有上映日期），但考虑到多部电影具有相同名称的情况，我试图将它们与上映日期区分开来. 有些电影没有指定上映日期，有些电影没有指定标签。

我试图在指定发布日期并且匹配时，或者当它在电影的标签中并且也匹配时获得结果。如果我无法将日期与这些属性之一匹配，我不想要任何结果作为回报

这是我当前的查询：

PREFIX  dbo:  <http://dbpedia.org/ontology/>
PREFIX  xsd:  <http://www.w3.org/2001/XMLSchema#>
PREFIX  rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX  foaf: <http://xmlns.com/foaf/0.1/>
    
SELECT DISTINCT ?film  ?aname
WHERE {
    ?film  a             dbo:Film ;
           foaf:name     "A Nightmare on Elm Street"@en ;
           dbo:starring  ?a .
    ?a     foaf:name     ?aname
    OPTIONAL
      { ?film  dbo:releaseDate  ?rd
        BIND(year(xsd:date(?rd)) AS ?rrd)
        FILTER ( ( ?rd = "1984-04-30"^^xsd:date ) || ( ?rrd = 1984) )
      }
    OPTIONAL
      { ?film  rdfs:label  ?lab
        FILTER regex(?lab, "1984", "i")
        FILTER ( lang(?lab) = "en" )
      }
  }

回答

我认为你在OPTIONAL这里滥用了。相反，您应该查看UNION. 有什么不同？

SELECT ?person ?child
WHERE {
?person a :Person .
OPTIONAL {?person :hasSon ?child}
OPTIONAL {?person :hasDaughter ?child}
}

将返回每个人，并可选择返回他们的儿子/女儿。然而，这也将返回没有任何孩子的人。

相反，类似于：

SELECT ?person ?child
WHERE {
?person a :Person .
{?person :hasSon ?child}
UNION
{?person :hasDaughter ?child}
    }

只会返回至少有一个儿子或女儿的人。

现在，在您的示例中，我有一个这样的查询：

PREFIX  dbo:  <http://dbpedia.org/ontology/>
PREFIX  dbp:  <http://dbpedia.org/property/>
PREFIX  xsd:  <http://www.w3.org/2001/XMLSchema#>
PREFIX  rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX  foaf: <http://xmlns.com/foaf/0.1/>
    
SELECT DISTINCT ?film  ?aname
WHERE {
    ?film  a             dbo:Film ;
           foaf:name     "A Nightmare on Elm Street"@en ;
           dbo:starring  ?a .
    ?a     foaf:name     ?aname
   
      { ?film  dbp:released  1984}
    UNION
      { ?film  rdfs:label  ?lab
        FILTER regex(?lab, "1984", "i")
        FILTER ( lang(?lab) = "en" )
      }
  }

请注意，我使用了dbp:released似乎有效的属性。

似乎用于发布的属性在电影中是不一致的，即某些用途dbp:released，其他用途dbo:releaseDate。

如果这是一个问题，您当然可以UNION在查询中添加另一个语句来处理不同的情况。

还有一件事：有许多三元组具有推理功能，推理可以帮助处理各种此类情况（消歧、同一事物的多个属性等）

以上是当多部电影在DBpedia中具有相同的名称时，无法获取给定电影名称的演员姓名的全部内容。
THE END
分享
二维码
< <上一篇
下一篇>>