如何在Haskell中修改RWST环境变量？

html5 • • 问答

我正在尝试在名为“GLFW-b-Demo”的现有项目上构建自己的项目。

它显然使用称为“RWST”的东西来模拟环境和状态：

data Env = Env
    { envEventsChan    :: TQueue Event
    , envWindow        :: !GLFW.Window
    , envGear1         :: !GL.DisplayList
    , envGear2         :: !GL.DisplayList
    , envGear3         :: !GL.DisplayList
    , envPlane         :: !GL.DisplayList
    , envBlobs         :: ![Blob]
    , envZDistClosest  :: !Double
    , envZDistFarthest :: !Double
    }

data State = State
    { stateWindowWidth     :: !Int
    , stateWindowHeight    :: !Int
    , stateXAngle          :: !Double
    , stateYAngle          :: !Double
    , stateZAngle          :: !Double
    , stateGearZAngle      :: !Double
    , stateZDist           :: !Double
    , stateMouseDown       :: !Bool
    , stateDragging        :: !Bool
    , stateDragStartX      :: !Double
    , stateDragStartY      :: !Double
    , stateDragStartXAngle :: !Double
    , stateDragStartYAngle :: !Double
    }

type Demo = RWST Env () State IO

从那个环境中检索一些东西很容易：

blobs <- asks envBlobs

但我还需要能够修改这些“变量”的值。我是否需要将其移动到状态，以便能够更改它的值，或者我是否还可以修改事物的“env”部分的内容？

回答

但我还需要能够修改这些“变量”的值。我是否需要将其移动到状态，以便能够更改它的值，或者我是否还可以修改事物的“env”部分的内容？

这取决于您是要在您控制下的计算中“本地”修改这些 env 值，还是要为之后可能出现的任何可能的计算修改它们。

在第一种情况下，您可以通过使用local：

local :: (r -> r) -> RWST r w s m a -> RWST r w s m a

当RWST我们传递给的计算local退出时，环境中的值r将返回到它们的原始版本，不被r -> r函数修改。

但是，如果您希望更改具有“粘性”，则需要将这些值移动到状态并使用诸如putor 之类的函数modify。

一个例子：

import Control.Monad.IO.Class
import Control.Monad.Trans.RWS.Strict

action :: RWST Int () Char IO ()
action = do
  local succ $ do -- affects only the nested action
    v <- ask 
    liftIO $ print v
  do
    v <- ask 
    liftIO $ print v -- isn't affected by local
  modify succ -- change seen by the following actions
  do
    s <- get 
    liftIO $ print s -- is affected by modify

main :: IO ()
main = do
  (_, _, _) <- runRWST action 0 'a'
  return ()
-- Results:
-- 1
-- 0
-- 'b'

以上是如何在Haskell中修改RWST环境变量？的全部内容。
THE END
分享
二维码
< <上一篇
下一篇>>